home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 7
/
FM Towns Free Software Collection 7.iso
/
data
/
nyan_e2
/
set_nyan.plt
< prev
next >
Wrap
Text File
|
1993-11-30
|
33KB
|
1,214 lines
var modem[40]; /* modem 種別 /NoMNPAT/MNPAT/会社名モデム機種名 */
var telno[30]; /* 電話番号 */
var telty[10]; /* 回線の種別 1200|2400|2400T|9600 */
var telno2[30]; /* 電話番号(Retry) */
var telty2[10]; /* 回線の種別(Retry) 1200|2400|2400T */
var telno3[30]; /* 電話番号(Retry) */
var telty3[10]; /* 回線の種別(Retry) 1200|2400|2400T */
var line[5]; /* プッシュ回線か,ダイヤル回線か T/P */
var id[10]; /* NIFTYのユーザID */
var pass[10]; /* パスワード */
var logd[30]; /* ログ格納用ディレクトリ(最後の\はなし) */
var logc1[30]; /* 会議室ログマージディレクトリ1 */
var logc2[8]; /* 会議室ログマージディレクトリ2 */
var logh1[30]; /* HPログマージディレクトリ */
var logm1[30]; /* メールログマージディレクトリ */
var logb1[30]; /* 掲示板ログマージディレクトリ1 */
var logb2[8]; /* 掲示板ログマージディレクトリ2 */
var loga1[30]; /* 案内ログマージディレクトリ1 */
var loga2[8]; /* 案内ログマージディレクトリ2 */
var forum[500]; /* フォーラム名( 「/」 で複数) */
var hp[500]; /* HP ID/HPパスワード/HP名( 「,」 で複数) */
var proc[5]; /* 処理要求.Down:DownOnly, Up:UpOnly, Both:Both*/
var st[5]; /* file受信Status */
var Treq[10]; /* Make Title Requset */
var Mode[4]; /* 「AUTO」or「OPER」 タイマ通信時のみAUTOとする */
var Rmail[10]; /* RMAIL実行フォーラム名(SysOp or SubSysOpのみ) */
var Smail[10]; /* SMAIL実行フォーラム名 */
var mail[3]; /* NEW:(NEW and SAV), ALL:(ALL and DEL)で動作 */
var FmgrP[30]; /* 呼び出すパイロットのpath名 */
var FmgrF[15]; /* 呼び出すパイロットの呼出し名(#file) */
var SetupF[15]; /* Setup File Name */
var Itime[6]; /* Manual Mode Alarm Interval Time */
var MesType[3]; /* 会議室の形式 (NEW or OLD) */
%mrgsuff {.ALL}; /* マージファイルの拡張子を指定する */
var logl[30]; /* ライブラリリスト保存親ディレクトリ */
var logf[30]; /* ライブラリデータ保存ディレクトリ */
var lib[500]; /* ライブラリ名( 「/」 で複数) */
var BILL[2]; /* 課金情報の取得の是非 */
var Handle[500]; /* ハンドル名 IDorHP/ハンドル名( 「,」 で複数) */
var DivDisp[4]; /* {ORI}→コメントが下,{REV}→コメントが上 */
var InsHan[5]; /* {HEAD}→「ハンドル:」 ,{TAIL}→「<ハンドル」 */
var LIST[5]; /* ライブラリリストの取得形式 (リザーブ) */
var patio[200]; /* パティオ ID/パスワード/PATIO名(「,」で複数) */
var GUEST[3]; /* HP,パティオ開設者が「GUEST」をするかの是非 */
var WTIME[6]; /* 時刻指定通信時の開始時刻のデフォルト */
var PRINTER[5]; /* 使用するプリンタの種類 {fm}or{esc/p} */
var rtn[700];
var cugname[10]; /* CUGの設定 */
var tmpdir[30];
var R[3];
var G[3];
var B[3];
%CloseAllMemo{
case(@mcheck !=0,
{Yes},{ loop({ mclose(2);
im(@mcheck !=0)
});
});
};
%allclear{
loop({
case(@mlast<>{0},
{Yes},{case(@mcheck,{0},{mopen(1); }); mclose(3);
im({Yes});
},{No},{ im({No});
});
});
};
%setcdir2 {[dir]
%dir2 @case(@nochar(dir),
2,{im(dir|{\})},,{im(dir)});
setcdir(dir2);
};
%getcdir2 {
case(@nochar(@getcdir),
3,{im(@getchar(@getcdir,1,2));
},,{im(@getcdir);
});
};
%click {\n (右クリックで終了すると、未設定とみなします)};
%YesNo2{[MSG,CMD]
loop({
select(MSG,9999,{im({Yes});
},{ O K },{CMD; im({No});
},{ N G },{im({No});
});
});
};
/********** 設定処理ルーチン群 **********/
%current @getcdir2;
%curfile current|{\MOPSET.PLP};
%setloadf{
footnote({ 設定情報が格納されたファイルを指定してください});
setcdir2(current);
%file @filesel({USR});
%fname @head(file,{.})|{.USR};
footnote({});
case(@filechk(fname),
{Yes}, {copyfile(fname,curfile);
NyanInit(current);
postproc:={thru};
SetupF :=fname;
},{No},{select(
{指定のファイル「}|fname|{」が存在しません},10,,{確 認});
});
im(@filechk(fname)<>{Yes});
};
%setat{
var type[10];
type := @select({ どういうタイプのモデムですか?}
,99999,{im({})},
{ 1200 MNPなし }, {im({1200n})},
{ 2400 MNPなし }, {im({2400n})},
{ 2400(端末速度2400) MNPあり }, {im({2400m})},
{ 2400(端末速度4800) MNPあり }, {im({4800m})},
{ 2400以上(端末速度9600以上) MNPあり }, {im({9600m})}
);
case(type<>{},{Yes},{
%a @input({ ATコマンド設定してください.例「ATX3\N3\V1\Q3\J0」},,
{AT}|@head(modem,{/}));
case(a<>{},{Yes},{
case(@getchar(a,1,2),
{AT},{
case( a = @head(a,{\}),
{Yes},{modem:=@getchar(a,3,999)|{/}|
@getchar(a,3,999)|{/AT直接指定_}|type;
},,{ modem:=@getchar(a,3,999)|{/}|
{/AT直接指定_}|type;
});
}, ,{setat;
});
});
});
};
%FUJITSU{
select({モデムの機種を選んでください.現在は「}|NowModem|{」です},
9999,{},
{内蔵1200}, {modem:={X3//内蔵1200_1200n}},
{内蔵2400}, {modem:={X3/\N3\V1\Q3\J0%C0/内蔵2400_9600m}},
{富士通 PM1200F},{modem:={X3//PM1200F_1200n}},
{富士通 PM2400F},{modem:={X3/\N3\V1\Q3\J0%C0/PM2400F_9600m}},
{富士通 PM2400FII},{modem:={X3/\N7\Q3\J0\V2%C0/PM2400FII_9600m}},
{富士通 OAMD-301},{modem:={X3&D2/\N3\Q3\J0\V2/OAMD-301_9600m}},
{メニューに戻る},{loopon:={Yes};
});
};
%AIWA{
select({モデムの機種を選んでください.現在は「}|NowModem|{」です},
9999,{},
{AIWA PV-A1200},{modem:={X3//PV-A1200_1200n}},
{AIWA PV-A2400},{modem:={X3//PV-A2400_2400n}},
{AIWA PV-A2400MNP4},{modem:={&D2/&M4\Q1/PV-A2400MNP4_9600m}},
{AIWA PV-A24MNP5},{modem:={X3&D2/\N3\Q3\J0/PV-A24MNP5_9600m}},
{AIWA PV-A24V42},{modem:={X3&D2/\N3\Q3\J0/PV-A24V42_9600m}},
{AIWA PV-M24},{modem:={X3&D2/\N3\Q3\J0\V2/PV-M24_9600m}},
{AIWA PV-M24M5},{modem:={X3&D2/\N3\Q3\J0\V2/PV-M24M5_9600m}},
{AIWA PV-M24B5},{modem:={X3&D2/\N3\Q3\J0\V2%C0/PV-M24B5_9600m}},
{AIWA PV-A96V5},{modem:={X3&D2/\N3\Q3\J0\V2%C0/PV-A96V5_9600m}},
{メニューに戻る},{loopon:={Yes};
});
};
%OMRON {
select({モデムの機種を選んでください.現在は「}|NowModem|{」です},
9999,{},
{OMRON MD1200},{modem:={X3//MD1200_1200n}},
{OMRON MD12FS},{modem:={X3//MD12FS_1200n}},
{OMRON MD2400F},{modem:={X3/\N3\V1\Q2\J0/MD2400F_2400m}},
{OMRON MD24FB5V},{modem:={X4/\N3\Q2\J0\V2%C0/MD24FB5V_9600m}},
{OMRON MD24FP4},{modem:={X3/\N3\Q2\J0/MD24FP4_2400m}},
{OMRON MD24FP4II},{modem:={X3&P2/\N3\Q2\J0/MD24FP4II_9600m}},
{OMRON MD24FP5V},{modem:={X3/\N3\Q2\J0\V2%C0/MD24FP5V_9600m}},
{OMRON MD24FS4},{modem:={X3/\N3\Q2\J0/MD24FS4_2400m}},
{OMRON MD24FS5},{modem:={X3/\N3\Q2\J0/MD24FS5_2400m}},
{OMRON MD24FS7},{modem:={X3/\N3\Q2\J0/MD24FS7_2400m}},
{メニューに戻る},{loopon:={Yes};
});
};
%EPSON {
select({モデムの機種を選んでください.現在は「}|NowModem|{」です},
9999,{},
{EPSON SR-120S},{modem:={X3//SR-120S_1200n}},
{EPSON SR-240AT},{modem:={X3//SR-240AT_2400n}},
{EPSON SR-240V},{modem:={X3\V2/N1&K1%C0/SR-240V_9600m}},
{メニューに戻る},{loopon:={Yes};
});
};
%NEC {
select({モデムの機種を選んでください.現在は「}|NowModem|{」です},
9999,{},
{NEC COMSTAR 2424},{modem:={X3/\N3\Q2/COMSTAR 2424_2400m}},
{メニューに戻る},{loopon:={Yes};
});
};
%SONY {
select({モデムの機種を選んでください 現在は「}|NowModem|{」です},
9999,{},
{SONY IT-V1200},{modem:={X3//IT-V1200_1200n}},
{メニューに戻る},{loopon:={Yes};
});
};
%MICROCORE{
select({モデムの機種を選んで下さい 現在は「}|NowModem|{」です},
9999,{},
{MICROCORE MC24PA5},{modem:={X3/\N3\Q2\J0\X1%C0/MC24PA5_9600m}},
{メニューに戻る},{loopon:={Yes};
});
};
%setmodem{
var loopon[4];
%NowModem @head(@tail(modem,{/}),{_});
loop({
loopon:={No};
select({ メーカーを選んで下さい.現在のモデムは「}|
NowModem|{」です},99999,{
},{ FUJITSU },{FUJITSU;
},{ AIWA },{AIWA;
},{ OMRON },{OMRON;
},{ EPSON },{EPSON;
},{ NEC },{NEC;
},{ SONY },{SONY;
},{ マイクロコア },{MICROCORE;
},{ ATコマンド直設定 },{setat;
},{ 変更しない },{
});
im(loopon={Yes});
});
};
%settelno{
%a @input({ 近くのNiftyの電話番号を設定してください.例「0559235038」},,
telno);
case(a<>{},{Yes},{telno:=a});
};
%settelty{
%name @case(telty,
{1200},{im({1200 ROAD1})},
{2400},{im({2400 ROAD1})},
{2400T},{im({2400 ROAD2})},
{9600},{im({9600 ROAD3})},
,{im({設定なし})} );
select({ アクセス・ポイントのタイプを選んでください.現在は「}|name|{」です},99999,{
},{ 変更しない },{
},{ 回線速度=1200 ROAD1 },{telty :={1200}
},{ 回線速度=2400 ROAD1 },{telty :={2400}
},{ 回線速度=2400 ROAD2 },{telty :={2400T}
},{ 回線速度=9600 ROAD3 },{telty :={9600}
});
};
%setline{
%name @case(line,
{T},{im({プッシュ回線})},
{P},{im({ダイヤル回線})},
,{im({設定なし})} );
select({ 電話回線のタイプを選んでください.現在は「}|name|{」です}
,99999,{},
{ 変更しない },{},
{ プッシュ回線 },{line:={T}},
{ ダイヤル回線 },{line:={P}})
};
%settel2{
loop({
select({ 設定する項目を選択してください},99999,{im({No})
},{最寄りのNiftyのアクセスポイントの電話番号},{
%a @input({ 近くのNiftyの電話番号を設定してください.}|
{例「0559235038」},,telno2);
case(a<>{},{Yes},{telno2 := a});
im({Yes});
},{最寄りのアクセスポイントの種別(速度・ROAD)},{
%name @case(telty2,
{1200},{im({1200 ROAD1})},
{2400},{im({2400 ROAD1})},
{2400T},{im({2400 ROAD2})},
{9600},{im({9600 ROAD3})},
,{im({設定なし})} );
select({ アクセス・ポイントのタイプを選んでください.}|
{現在は「}|name|{」です},99999,{
},{ 変更しない },{
},{ 回線速度=1200 ROAD1 },{telty2:={1200}
},{ 回線速度=2400 ROAD1 },{telty2:={2400}
},{ 回線速度=2400 ROAD2 },{telty2:={2400T}
},{ 回線速度=9600 ROAD3 },{telty2:={9600}
});
im({Yes});
},{第2候補の設定処理を終了する},{im({No});
});
});
};
%settel3{
loop({
select({ 設定する項目を選択してください},99999,{im({No})
},{最寄りのNiftyのアクセスポイントの電話番号},{
%a @input({ 近くのNiftyの電話番号を設定してください.}|
{例「0559235038」},,telno3);
case(a<>{},{Yes},{telno3 := a});
im({Yes});
},{最寄りのアクセスポイントの種別(速度・ROAD)},{
%name @case(telty3,
{1200},{im({1200 ROAD1})},
{2400},{im({2400 ROAD1})},
{2400T},{im({2400 ROAD2})},
{9600},{im({9600 ROAD3})},
,{im({設定なし})} );
select({ アクセス・ポイントのタイプを選んでください.}|
{現在は「}|name|{」です},99999,{
},{ 変更しない },{
},{ 回線速度=1200 ROAD1 },{telty3 :={1200}
},{ 回線速度=2400 ROAD1 },{telty3 :={2400}
},{ 回線速度=2400 ROAD2 },{telty3 :={2400T}
},{ 回線速度=9600 ROAD3 },{telty3 :={9600}
});
im({Yes});
},{第3候補の設定処理を終了する},{im({No});
});
});
};
%setintv{
loop({
%a @input({ アラーム間隔時間を秒単位で入力してください},,
Itime);
case(@nochar(a)<6,
{Yes}, {Itime:=a; im({No});
},{No},{footnote({ 6桁以内で指定してください}); im({Yes});
});
});
footnote({});
};
%setbill{
var msg[10];
case(BILL={},{Yes},{BILL:={OK}});
case(BILL,{OK},{msg:={する}},{NG},{msg:={しない}},
{P},{msg:={するかも?}});
select({ 課金情報を取得しますか? (現在は「取得}|msg|{」)},
9999,{
},{ 取得する },{BILL:={OK};
},{ 取得しない },{BILL:={NG};
},{ 適時取得 },{BILL:={P};
});
};
%setmail{
%dspmail{
case(mail,
{NEW},{ im({New & Sav});
},{ALL},{ im({All & Del});
},, { im({未設定});
});
};
select({ メール受信方法を選んでください.現在は「}|@dspmail|{」です}
,99999,{},
{ 変更しない },{},
{新規受信,既読保存 (New & Sav)},{ mail:={NEW} },
{全受信, 既読削除 (All & Del)},{ mail:={ALL} });
};
%setlogx3{
%mkdir2{[path]
var drive[2];
var dir[80];
var tarpath[80];
var ret[4];
ret:={No};
dispoff({Yes});
case(@setcdir2(path),{No},{
drive:=@body(path,,{:});
dir:=@body(path,{\});
case(drive<>{},
{Yes},{
case(@setcdir2(drive|{:}),
{Yes},{
YesNo2({「}|path|{」 を作成します},{
tarpath:=drive|{:};
loop({
tarpath:=tarpath|{\}|@head(dir,{\});
dir:=@body(dir,{\});
case(@setcdir2(tarpath),{No},{
command({mkdir }|tarpath);
});
im( dir<>{} );
});
ret:={Yes};
});
},{No},{
select({ 「}|drive|{」ドライブは使えません}
,10,{}, { 確認 },{});
});
},{No},{
select({ ドライブ名が設定されていません}
,10,{}, { 確認 },{});
});
});
dispoff({No});
im( ret );
};
%setlogx2{[old]
case(@mkdir2(old),
{Yes},{logx := LOGX;
},{No},{
LOGX:=@input({ 格納先を設定してください.例「B:」,}|
{「C:\NIF」\n (英小文字は使わないでください)}
,,old);
case(@getchar(LOGX,@nochar(LOGX),1)={\},{Yes},
{LOGX:=@body(LOGX,,{\})});
case(LOGX<>{},{Yes},{
case(@setcdir2(LOGX),{Yes},{logx := LOGX},
,{setlogx2(LOGX)})
})
});
};
var LOGX[80];
LOGX:=@input({ 格納先を設定してください.例「B:」,「C:\NIF」}|
{\n (英小文字は使わないでください)},,logx);
case(@getchar(LOGX,@nochar(LOGX),1)={\},{Yes},
{LOGX:=@body(LOGX,,{\})});
case(LOGX<>{},
{Yes}, {case(@setcdir2(LOGX),{Yes},{logx := LOGX},
,{setlogx2(LOGX)})
},{No},{logx:=LOGX;
})
};
%setlogx{[logdrv]
var logx[20];
logx := logdrv;
%cur @case(logx,
{}, {im({未設定})},
,{im({パスの直接設定})}
);
select({文書を格納する装置は? 現在は「}|cur|{」}
,99999,{},
{変更しない},{},
{パスを直接入力する}, {setlogx3}
);
im(logx);
};
%setlogy{[msg,dmy,init]
%path @input(msg,dmy,init);
case(path<>{} && @getchar(path,1,1)<>{\},
{Yes}, { im({\}|path);
},{No},{ im(path);
});
};
%setlogd{
logd:=@setlogx(logd);
};
%setlogl{
logl:=@setlogx(logl);
};
%setlogf{
logf:=@setlogx(logf);
};
%setlogb{
footnote({ マージ処理不要ならば,マウス右ボタンをクリック});
logb1 := @setlogx(logb1);
footnote({});
};
%setlogc{
footnote({ マージ処理不要ならば,マウス右ボタンをクリック});
logc1 := @setlogx(logc1);
footnote({});
};
%setlogh{
footnote({ マージ処理不要ならば,マウス右ボタンをクリック});
logh1 := @setlogx(logh1);
footnote({});
};
%setlogm{
footnote({ マージ処理不要ならば,マウス右ボタンをクリック});
logm1 := @setlogx(logm1);
footnote({});
};
%setid{
%setid2{[old]
%a @input({ユーザIDは8文字です。 例「BBB00123」},,
old);
case(a<>{},{Yes},{
case(@nochar(a)=8,{Yes},{id := a},
,{setid2(a)})
})
};
%a @input({ NiftyのユーザIDを設定してください.例「AAA00321」},,
id);
case(a<>{},{Yes},{
case(@nochar(a)=8,{Yes},{id := a},
,{setid2(a)})
})
};
%setpass{
%setpassn{
%setpass2{[old]
%a @input({ パスワードは8文字以下です.例「MIKENEKO」},,
old);
case(a<>{},{Yes},{
case(@nochar(a)<=8,{Yes},{pass := a},
,{setpass2(a)})
})
};
%a @input({ Niftyのパスワードを設定してください.例「POCHIINU」},,
pass);
case(a<>{},{Yes},{
case(@nochar(a)<=8,{Yes},{pass := a},
,{setpass2(a)})
})
};
%name @case(pass,
{},{im({アクセス時に入力})},
,{im({予め設定済})} );
select({ パスワードを設定しておきますか? 現在は「}|name|{」です。}
,99999,{},
{ 変更しない },{},
{ 他の人が使うので,アクセス時に入力する }, {pass :={} },
{ 専用なので,予め設定しておく }, {setpassn })
};
%sethp{
var dispOne[1000];
%checkHP{[text]
%topname @head(text,{,});
%id @head(topname,{/});
%pass @body(topname,{/},{/});
%hpname @tail(topname,{/});
case(@nochar(id)==8 && @nochar(pass)<=8 && @nochar(hpname)<=8,
{Yes},{
case(topname,
text,{im({Yes})},
,{checkHP(@body(text,{,}))})
},,{
footnote({「}|topname|{」は文字数が合いません});
im({No})
})
};
dispOne:=hp;
loop({
%a @input({巡回するHPを設定してください\n}|
{ 形式「ID/パスワード/名前,ID2/パスワード2/名前2,,,」\n}|
{ ID:HP主催者のID パスワード:HPのパスワード \n}|
{ 名前:英字8文字以下の名前(任意の識別名)\n}|
{ 例「PFF00570/HACHIKOU/MOPROOM,}|
{KKK00123/AKITAKEN/FUFUFU」}|click,,
dispOne);
case(a<>{},
{Yes},{
dispOne:=a;
case(@checkHP(a),{Yes},{hp:=a; im({No})},,{im({Yes})})
},{No},{
YesNo2({ HPを受信しなくてよろしいですか?},{hp:={};
});
im({No});
})
});
footnote({});
};
%checkForum{[text]
%topname @head(@head(text,{/}),{(});
%lstname @head(@tail(text,{/}),{(});
%checkCcs{[rooms]
var roomnos[80];
var roomset[20];
var judge[3];
%chkroom{
case(roomno<1 || roomno>20,
{Yes},{ footnote({会議室「}|roomno|{」の値が不当です});
judge:={No};
});
};
roomnos:=rooms;
judge:={Yes};
case(roomnos<>{} && roomnos<>{ALL},{Yes},{
loop({
roomset:=@head(roomnos,{,});
roomnos:=@body(roomnos,{,});
loop({
%roomno @head(roomset,{-});
chkroom;
roomset:=@body(roomset,{-});
im(roomset<>{});
});
im(roomnos<>{});
});
});
im(judge);
};
case(@nochar(topname)<=8,
{Yes},{
case( @checkCcs( @body(@head(text,{/}),{(},{)}) ),
{Yes},{ case(topname,
lstname,{im({Yes})},
,{checkForum(@body(text,{/}))})
},,{ im({No});
});
},,{
footnote({「}|topname|{」は8文字以上です});
im({No})
})
};
%setforum{
var dispOne[1000];
dispOne:=forum;
loop({
%a @input({巡回するフォーラム名と会議室番号を設定してくださ}|
{い\n}|
{ フォーラム名の後にカッコでくくって会議室番号を}|
{指定\n}|
{ します.会議室番号番号を省略すると,全会議室を}|
{指定\n}|
{ したことになります.\n}|
{ 例「FSKIER(1,2,3)/FTOWNS1/FFMPRO(9)」}|click,,
dispOne);
case(a<>{},
{Yes},{
dispOne:=a;
case(@checkForum(a),{Yes},{forum:=a; im({No})},
,{im({Yes})})
},{No},{
YesNo2({ フォーラムを受信しなくてよろしいですか?},
{forum:={};
});
im({No});
})
});
footnote({});
};
%setlib{
var dispOne[1000];
dispOne:=lib;
loop({
%a @input({巡回するフォーラム名とライブラリ番号を設定してく}|
{ださい\n}|
{ フォーラム名の後にカッコでくくってライブラリ番}|
{号を\n}|
{ ひとつずつ指定します.ライブラリ番号を省略する}|
{と,\n}|
{ ライブラリのメニューだけを取得します.\n}|
{ 例「FTOWNS1/FFMUSER(1,2)/FFMPRO(10)」}|click,,
dispOne);
case(a<>{},
{Yes},{
dispOne:=a;
case(@checkForum(a),{Yes},{lib:=a; im({No})},
,{im({Yes})})
},{No},{
YesNo2({ ライブラリは未設定でよろしいですか?},
{lib:={};
});
im({No});
})
});
footnote({});
};
%setdiv{
var msg[10];
case(DivDisp={},{Yes},{DivDisp:={ORI}});
case(DivDisp,{ORI},{msg:={下}},{REV},{msg:={上}});
select({ 返信文書は画面のどちらで書きますか? }|
{(現在は「}|msg|{」です)},9999,{
},{ 上で書く },{DivDisp:={REV};
},{ 下で書く },{DivDisp:={ORI};
});
};
%setins{
var msg[10];
case(InsHan={},{Yes},{InsHan:={TAIL}});
case(InsHan,{HEAD},{msg:={先頭}},{TAIL},{msg:={末尾}});
select({HPタイトルへのハンドル挿入タイプ(現在は「}|msg|{タイプ」)},
9999,{
},{ 先頭タイプ (「ハンドル:~」) },{InsHan:={HEAD};
},{ 末尾タイプ (「~<ハンドル」) },{InsHan:={TAIL};
});
};
%setpatio{
var dispOne[1000];
%checkPatio{[text]
%topname @head(text,{,});
%id @head(topname,{/});
%pass @body(topname,{/},{/});
%pationame @tail(topname,{/});
case(@nochar(id)==8 && @nochar(pass)<=8 &&
@nochar(pationame)<=8,
{Yes},{
case(topname ,
text,{im({Yes})},
,{checkPatio(@body(text,{,}))})
},,{
footnote({「}|topname|{」は文字数が合いません});
im({No})
})
};
dispOne:=patio;
loop({
%a @input({巡回するパティオを設定してください\n}|
{ 形式「ID/パスワード/名前,ID2/パスワード2/名前2,,,」\n}|
{ ID:PATIO主催者のID パスワード:PATIOのパスワード\n}|
{ 名前:英字8文字以下の名前(任意の識別名)\n}|
{ 例「PFF00570/HACHIKOU/MOPROOM,}|
{KKK00123/AKITAKEN/FUFUFU」}|click,,
dispOne);
case(a<>{},
{Yes},{
dispOne := a;
case(@checkPatio(a),{Yes},{ patio:=a; im({No}) },
,{ im({Yes}) })
},{No},{
YesNo2({ パティオを受信しなくてよろしいですか?},
{hp:={};
});
im({No});
})
});
footnote({});
};
%setguest{
var msg[10];
case(GUEST={},{Yes},{GUEST:={OK}});
case(GUEST,{OK},{msg:={する}},{NG},{msg:={しない}});
select({ 「GUEST」を発行しますか? (現在は「発行}|msg|{」)},
9999,{
},{ 発行する },{GUEST:={OK};
},{ 発行しない },{GUEST:={NG};
});
};
%setwtime{
var ReqHM[10];
loop({
ReqHM:=@input( {何時何分に起動しますか?.\n}|
{ 4桁の数字(hhmm)で返答して下さい.}|
{(hh=00~23,mm=00~59)},,WTIME);
case(@nochar(ReqHM)=4 || ReqHM={},{Yes},{
im({No});
},,{footnote({ 4桁の数字(hhmm)で入力してください});
im({Yes})
});
});
footnote({});
case(@nochar(ReqHM)=4,{Yes},{WTIME:=ReqHM});
};
%settmp{
%DRIVE{[Dri]
case(@setcdir2(Dri),
{Yes},{ tmpdir:=Dri;
},{No},{footnote({ そのドライブは使用できません});
tmpdir:={};
});
};
loop({
case(tmpdir={},{Yes},{tmpdir:=@getchar(current,1,2)});
select({ どのドライブを作業用にしますか?(現在は「}
|@getchar(tmpdir,1,1)|{」ドライブ)},9999,,
{ A },{DRIVE({A:})},{ B },{DRIVE({B:})},
{ D },{DRIVE({D:})},{ E },{DRIVE({E:})},
{ F },{DRIVE({F:})},{ G },{DRIVE({G:})},
{ H },{DRIVE({H:})},{ I },{DRIVE({I:})},
{ J },{DRIVE({J:})},{ K },{DRIVE({K:})},
{ L },{DRIVE({L:})},{ M },{DRIVE({M:})},
{ N },{DRIVE({N:})},{ O },{DRIVE({O:})},
{ P },{DRIVE({P:})});
im(tmpdir={});
});
footnote({});
};
%setprinter{
var msg[5];
case(PRINTER={},{Yes},{PRINTER:={fm}});
case(PRINTER,{fm},{msg:={FM}},{esc/p},{msg:={ESC/P}});
select({ どちらのプリンタを使いますか? (現在は「}|msg|{」プリンタ)},
9999,{
},{ FM },{PRINTER:={fm};
},{ ESC/P },{PRINTER:={esc/p};
});
};
%setfmgr{
footnote({ 呼び出すパイロットを指定してください}|
{(右クリックで設定なし)});
case(FmgrP<>{},{Yes},{ setcdir2(FmgrP); });
%f @filesel({PLT});
footnote({});
case(f={},
{Yes}, {FmgrP:={};
FmgrF:={};
},{No},{FmgrP:=@getcdir;
FmgrF:={#}|f;
});
};
%setRGB{
var r[5];
var g[5];
var b[5];
%Getnum{[LINE]
getchar(@getline(a,LINE,1),2,1);
};
%three{[col]
case(@nochar(col),1,{im({ }|col)},2,{im({ }|col)},
3,{im(col)});
};
case(R,{},{R:=50}); case(G,{},{G:=80}); case(B,{},{B:=50});
loop({
r:=@three(R);
g:=@three(G);
b:=@three(B);
%a @plane(
{c 背景色を設定してください\n}|
{c\n}|
{s / +30 / +30 / +30\n}|
{s / +5 / +5 / +5\n}|
{c R:}|r|{ G:}|g|{ B:}|b|{\n}|
{s / -5 / -5 / -5\n}|
{s / -30 / -30 / -30\n}|
{c\n}|
{s / 終 了 \n}
);
case(@Getnum(1),{1},{R:=R+30},{2},{G:=G+30},{3},{B:=B+30});
case(@Getnum(2),{1},{R:=R+5},{2},{G:=G+5},{3},{B:=B+5});
case(@Getnum(3),{1},{R:=R-5},{2},{G:=G-5},{3},{B:=B-5});
case(@Getnum(4),{1},{R:=R-30},{2},{G:=G-30},{3},{B:=B-30});
case(R>255,{Yes},{R:=255}); case(R<0,{Yes},{R:=0});
case(G>255,{Yes},{G:=255}); case(G<0,{Yes},{G:=0});
case(B>255,{Yes},{B:=255}); case(B<0,{Yes},{B:=0});
backclr(R,G,B);
case(@Getnum(5)==1,{Yes},{im({No})},{No},{im({Yes})});
});
};
%setcug{
loop({
%a @input({ CUGの名前を入力してください},,
cugname);
case(a<>{},
{Yes}, {cugname:=a; im({No});
},{No},{
YesNo2({ CUGは未設定でよろしいですか?},
{cugname:={};
});
im({No});
});
});
footnote({});
};
%minimum{
var a[150];
var msg1[6];
var msg2[6];
%Getnum{[LINE]
getchar(@getline(a,LINE,1),2,1);
};
%Getline{[LINE]
head(@getline(a,LINE,1),{\n});
};
%data{
msg1:=@Getnum(2);
case(msg1,1,{line:={P}},2,{line:={T}});
case(@Getline(3)<>{},{Yes},{telno:=@Getline(3)});
msg2:=@Getnum(4);
case(msg2,1,{telty:={1200}},2,{telty:={2400T}},
3,{telty:={9600}});
case(@Getline(5)<>{},{Yes},{id:=@Getline(5)});
case(@Getline(6)<>{},{Yes},{pass:=@Getline(6)});
case(@Getline(7)<>{},{Yes},{logd:=@Getline(7)});
};
%NowModem{
case(modem<>{},
{Yes},{ im(@head(@tail(modem,{/}),{_}));
},{No},{im({未設定});
});
};
loop({
case(line,{P},{msg1:={1}},{T},{msg1:={2}});
case(telty,{1200},{msg2:={1}},{2400T},{msg2:={2}},
{9600},{msg2:={3}});
a:=@plane(
{c 各設定を行ってください(通信に最低必要な項目です)\n}|
{c\n}|
{s モデムの種類(現在は「}|@NowModem|{」) / 選 択 \n}|
{r 電話回線の種類 / ダイヤルホン / プッシュホン \n}|
{t アクセスポイントの電話番号 /xxxxxxxxxxxxxxx\n}|
{r FENICS LOAD /ROAD1(1200)/ROAD2(2400)/ROAD3(9600)\n}|
{t NiftyのユーザID /xxxxxxxx\n}|
{t Niftyのパスワードパスワード /xxxxxxxx\n}|
{t 受信データの格納先 /xxxxxxxxxxxxxxxxxxxxxxxxxxxxxx\n}|
{c (英小文字は使用しないでください)\n}|
{c\n}|
{s / 終 了 \n},
msg1,telno,msg2,id,pass,logd,
);
case(@Getnum(1),1,{
setmodem;
data;
});
case(@Getnum(8),
0,{ data; im({Yes}); },
1,{
data;
case(modem<>{} && line<>{} && telno<>{} && telty<>{} &&
@nochar(id)=8 && logd<>{},
{Yes},{
case(pass<>{},
{Yes},{ im({No});
},{No},{
select({ 通信毎にパスワードを入力する}|
{のですか?},9999,{im({Yes});
},{ O K },{im({No});
},{ N G },{im({Yes});
});
});
},{No},{
select({ 未設定の項目がありますが?},9999,{im({Yes});
},{ 終了する },{im({No});
},{ 戻 る },{im({Yes});
});
});
});
});
};
%putplp{[id,data]
madd(1,id|@xc({09})|{:=}|@xc({7b})|data|@xc({7d})|{;\n});
};
%putusr{
case(mail={},{Yes},{mail:={NEW}});
case(BILL={},{Yes},{BILL:={OK}});
case(DivDisp={},{Yes},{DivDisp:={ORI}});
case(InsHan={},{Yes},{InsHan:={TAIL}});
case(PRINTER={},{Yes},{PRINTER:={fm}});
case(tmpdir={},{Yes},{tmpdir:=@getchar(current,1,2)});
CloseAllMemo;
mclear(1);
putplp({SetupF},SetupF);
putplp({modem},modem);
putplp({telno},telno);
putplp({telty},telty);
putplp({telno2},telno2);
putplp({telty2},telty2);
putplp({telno3},telno3);
putplp({telty3},telty3);
putplp({Rmail},Rmail);
putplp({Smail},Smail);
putplp({mail},mail);
putplp({FmgrP},FmgrP);
putplp({FmgrF},FmgrF);
putplp({line},line);
putplp({Itime},Itime);
putplp({R},R);
putplp({G},G);
putplp({B},B);
putplp({id},id);
putplp({pass},pass);
putplp({logd},logd);
putplp({loga1},loga1);
putplp({loga2},loga2);
putplp({logb1},logb1);
putplp({logb2},logb2);
putplp({logc1},logc1);
putplp({logc2},logc2);
putplp({logh1},logh1);
putplp({logm1},logm1);
putplp({logl},logl);
putplp({logf},logf);
putplp({tmpdir},tmpdir);
putplp({BILL},BILL);
putplp({DivDisp},DivDisp);
putplp({InsHan},InsHan);
putplp({Handle},Handle);
putplp({LIST},LIST);
putplp({GUEST},GUEST);
putplp({WTIME},WTIME);
putplp({PRINTER},PRINTER);
putplp({cugname},cugname);
putplp({forum},forum);
putplp({hp},hp);
putplp({patio},patio);
putplp({lib},lib);
putplp({rtn},rtn);
};
%SetLog{
loop({
select({ 設定する項目を選択してください},99999,{im({No})},
{掲示板ログのマージ先(ドライブ名・パス名)}, {setlogb; im({Yes}) },
{会議室ログのマージ先(ドライブ名・パス名)}, {setlogc; im({Yes}) },
{HPログのマージ先(ドライブ名・パス名)}, {setlogh; im({Yes}) },
{メールのマージ先(ドライブ名・パス名)}, {setlogm; im({Yes}) },
{マージ先設定処理を終了する}, {im({No})}
);
});
};
%settel{
loop({
select({ 設定する項目を選択してください},99999,{im({No})},
{電話回線の種類(ダイヤル/プッシュ回線)}, {setline; im({Yes})},
{最寄りのNiftyのアクセスポイントの電話番号}, {settelno; im({Yes})},
{最寄りのアクセスポイントの種別(速度・ROAD1/2)}, {settelty; im({Yes})},
{第2候補を設定する}, {settel2; im({Yes})},
{第3候補を設定する}, {settel3; im({Yes})},
{電話回線関係の設定処理を終了する}, {im({No})}
);
});
};
%setdata{
loop({
select({ 設定する項目を選択してください},99999,{im({No})},
{受信ログの格納先(ドライブ名・パス名)}, {setlogd; im({Yes})},
{ライブラリリストの格納先(ドライブ名・パス名)}, {setlogl; im({Yes})},
{ライブラリデータの格納先(ドライブ名・パス名)}, {setlogf; im({Yes})},
{受信データ設定処理を終了する}, {im({No})}
);
});
};
%setetc{
loop({
select({ 設定する項目を選択してください},99999,{im({No})},
{ 返信文書作成時の入力memoの上下}, {setdiv; im({Yes})},
{ HPタイトルへのハンドル挿入のタイプ}, {setins; im({Yes})},
{ 巡回するパティオの設定}, {setpatio; im({Yes})},
{ 「GUEST」の発行の是非(HP,パティオ開設者のみ) }, {setguest; im({Yes})},
{ CUGの設定}, {setcug; im({Yes})},
{ 時刻指定通信時の開始時刻のデフォルト}, {setwtime; im({Yes})},
{ 作業用ドライブの選択}, {settmp; im({Yes})},
{ 使用するプリンタの設定 (「FM」or「ESC/P」)}, {setprinter;im({Yes})},
{ 「外部呼出」で呼び出すパイロットの選択}, {setfmgr; im({Yes})},
{ 画面の背景色の設定}, {setRGB; im({Yes})},
{ その他の設定を終了する}, {im({No})}
);
});
};
%setcmds{
var IndexLine[82];
var flag[3];
%writedata{
write(logd|{\UP\INDEX.TXT},
{保 LIB :FTOWNS1 /02/ 0007:NYANE2X.EXE\n}|
{保 LIB :FTOWNS1 /02/ 0002:TXF199K.LZH\n}|
{保 LIB :FFMHOB /04/ 0190:MS_CMDS.EXE\n}|
{保 LIB :FFMUSER /01/ 0613:ZCOPY107.LZH\n}
);
};
case(logd<>{},{Yes},{
dispoff({Yes});
case(@setcdir2(logd),{Yes},{
command({mkdir }|logd|{\UP});
});
case(@fopen(logd|{\UP\INDEX.TXT}),
{Yes},{
flag:={};
loop({
IndexLine:=@fread;
case(IndexLine,
{保 LIB :FTOWNS1 /02/ 0007:NYANE2X.EXE\n},
{flag:={OK}; im({No})},
{保 LIB :FTOWNS1 /02/ 0002:TXF199K.LZH\n},
{flag:={OK}; im({No})},
{保 LIB :FFMHOB /04/ 0190:MS_CMDS.EXE\n},
{flag:={OK}; im({No})},
{保 LIB :FFMUSER /01/ 0613:ZCOPY107.LZH\n},
{flag:={OK}; im({No})},
{}, {flag:={NG}; im({No})},
, {im({Yes})
});
});
fclose;
case(flag<>{OK},{Yes},{writedata});
},{No},{
writedata;
});
dispoff({No});
});
};
var loopon[5];
var postproc[5];
var mainmes[15];
allclear;
footnote({ 変更する定義ファイルを選んでください (右クリックで新規作成)});
SetupF:=@filesel({USR});
footnote({});
dispoff({Yes});
case(SetupF<>{},{Yes},{
command({copy }|SetupF|{ TMP_SET.PLP});
#TMP_SET.PLP;
command({del TMP_SET.PLP});
});
dispoff({No});
putusr;
postproc:={sel};
case(SetupF<>{},{Yes},{mainmes:=SetupF},{No},{mainmes:={新規作成}});
loop({
loopon := {Yes};
select({設定する項目を選んでください《SETUP FILE : }|mainmes|{》},
99999,{},
{ 設定処理を終了する}, {loopon:={No}},
{ †必要最小限の基本設定 (これだけで通信はOK)† },{minimum},
{ タウンズに接続したモデムの種類(会社名,機種名) },{setmodem},
{ 電話回線関係の設定}, {settel},
{ NiftyのユーザID}, {setid},
{ Niftyのパスワード(通信時に入れることも可能)},{setpass},
{ 受信データの格納先(ドライブ名・パス名)}, {setdata},
{ ログのマージ先(ドライブ名・パス名)}, {SetLog},
{ メール受信方法}, {setmail},
{ 手動通信時のアラーム間隔時間の設定}, {setintv},
{ 課金情報取得の有無}, {setbill},
{ 巡回するライブラリの設定(複数可能)}, {setlib},
{ 巡回するHPの設定(複数可能)}, {sethp},
{ 巡回するフォーラムの設定(複数可能)}, {setforum},
{ その他の設定}, {setetc});
im(loopon)
});
case(postproc={sel},
{Yes},{
setcdir2(current);
case(@filechk(SetupF),
{Yes},{
loop({
select({変更した設定内容は?},99999,{im({Yes});
},{ 元のファイルに保存 },{
putusr;
mwrite(SetupF,1);
mwrite(curfile,1);
setcmds;
im({No});
},{ 指定ファイルに保存 },{
footnote({ 保存ファイルを指定してください});
%file @filesel({USR});
%fname @head(file,{.})|{.USR};
footnote({});
case(@nochar(@head(file,{.}))>0,{Yes},{
case(@filechk(fname),{Yes},{delfile(fname)});
SetupF:=fname;
putusr;
mwrite(fname,1);
mwrite(curfile,1);
});
setcmds;
im({No});
},{ 変更処理を中止 },{
%Reset @memo(1);
Reset;
im({No});
});
});
},{No},{
case(@nochar(id)>0,
{Yes},{ %fname id|{.USR};
SetupF:=fname;
putusr;
mwrite(fname,1);
mwrite(curfile,1);
});
setcmds;
});
});
allclear;